Esempio di aggiornamento di plug-in
Il seguente esempio confronta la versione di un plug-in installato con la versione che si trova in un campo Contenitore del file FileMaker Pro e aggiorna il plug-in, se necessario.
1.
Nel file della soluzione, creare una tabella denominata Aggiorna plug-in in cui salvare le informazioni sul plug-in.
2.
Definire i seguenti campi:
 
Nome del campo
Tipo di campo
Nome plug-in
testo
Versione richiesta del plug-in
numero
Versione installata del plug-in
calcolo (non salvato). Per il codice di esempio, vedere Calcolo versione plug-in client di seguito.
Stato del plug-in installato
calcolo (non salvato). Per il codice di esempio, vedere Calcolo stato di abilitazione plug-in client di seguito.
File del plug-in
Contenitore
3.
Creare un formato di nome Informazioni di aggiornamento del plug-in e aggiungerlo ai campi definiti nel passo 2.
4.
Creare il seguente script e denominarlo Installa plug-in:
Imposta cattura errori [Attivata]
Installa file plug-in [Aggiornamento dei plug-in::File plug-in]
#
#Gestisci errori
If [Get(UltimoErrore) ≠ 0]
If [Get(UltimoErrore) = 3]
Mostra finestra personalizz. [Aggiornamento dei plug-in::File plug-in & " non è stato installato. Assicurarsi che Consenti alle soluzioni di installare file sia selezionato nelle preferenze dei plug-in di FileMaker Pro."]
Else If [Get(UltimoErrore) = 1550]
Mostra finestra personalizz. [Aggiornamento dei plug-in::File plug-in & " è stato installato ma non inizializzato."]
Else If [Get(UltimoErrore) = 1551]
Mostra finestra personalizz. [Aggiornamento dei plug-in::File plug-in & " non è stato installato."]
Else
Mostra finestra personalizz. ["Errore generale" & Get(UltimoErrore) & " durante l'installazione" & Aggiornamento dei plug-in::File plug-in]
End If
End If
5.
Creare il seguente script e denominarlo Controlla versioni plug-in.
Vai al formato ["Informazioni di Aggiornamento dei plug-in"]
Vai a Record/Richiesta/Pagina [Primo]
Loop
If [Aggiornamento dei plug-in::Versione plug-in installata < Aggiornamento dei plug-in::Versione plug-in richiesta]
#Il plug-in deve essere installato o aggiornato.
Esegui script ["Installa plug-in"]
End If
Vai a Record/Richiesta/Pagina [Successivo; Esci dopo l'ultimo]
End Loop
6.
Creare il seguente script e denominarlo Controlla se attivato:
Imposta cattura errori [Attivata]
Esegui la ricerca [Ripristina]
#Ricerca "Attivato" nel campo di stato del plug-in installato
If[Get(ContaTrovati) ≠ 0]
Mostra finestra personalizz. ["Alcuni plug-in richiesti non sono attivati. Assicurarsi che Consenti alle soluzioni di installare file sia selezionato nelle preferenze dei plug-in di FileMaker Pro."]
End If
7.
Creare uno script all'avviamento denominato Script di Aggiornamento dei plug-in che faccia riferimento agli script di cui sopra nell'ordine quando il database viene aperto:
Esegui script ["Controlla versioni plug-in"]
Esegui script ["Controlla se attivato"]
Vai al formato [formato originale]
Calcolo versione plug-in client
Dichiara(
[
PosizioneNomePlug-in = Posizione(Get(PluginFMInstallati); Nome plug-in; 1; 1);
InizioVersionePlug-in = PosizioneNomePlug-in + Lunghezza(Nome plug-in) + 1;
FineVersionePlug-in = Posizione(Get(PluginFMInstallati); "; "; PosizioneNomePlug-in; 2);
LunghezzaVersionePlug-in = FineVersionePlug-in- InizioVersionePlug-in
];
If(ContaRicorrenze(Get(PluginFMInstallati); Nome plug-in) = 0; ""; Mezzo(Get(PluginFMInstallati); InizioVersionePlug-in; LunghezzaVersionePlug-in))
)
Calcolo stato di abilitazione plug-in client
Dichiara(
[
PosizioneNomePlug-in = Posizione(Get(PluginFMInstallati); Nome plug-in; 1; 1);
InizioStatoPlug-in = Posizione(Get(PluginFMInstallati); "; "; PosizioneNomePlug-in; 2) + 1;
FineStatoPlug-in = If(Posizione(Get(PluginFMInstallati); ""; PosizioneNomePlug-in; 1) > 0; Posizione(Get(PluginFMInstallati); ""; PosizioneNomePlug-in; 1); Lunghezza(Get(PluginFMInstallati)) + 1);
LunghezzaStatoPlug-in = FineStatoPlug-in - InizioStatoPlug-in
];
If(ContaRicorrenze(Get(PluginFMInstallati); Nome plug-in) = 0;
""; Mezzo(Get(PluginFMInstallati); InizioStatoPlug-in; LunghezzaStatoPlug-in))
)
Argomenti correlati 
Creazione di plug-in personalizzati
Get(PluginFMInstallati)
Installa file plug-in